Add tests for error handling

Document reason for breaking out update functions
2019-09-30 13:59:38 +02:00
parent f93c1aba93
commit 6f41733461
7 changed files with 342 additions and 85 deletions
@@ -0,0 +1,49 @@
+-module(mnesia_rocksdb_SUITE).
+
+-export([
+         all/0
+        , groups/0
+        , suite/0
+        , init_per_suite/1
+        , end_per_suite/1
+        , init_per_group/2
+        , end_per_group/2
+        , init_per_testcase/2
+        , end_per_testcase/2
+        ]).
+
+-export([error_handling/1]).
+
+-include_lib("common_test/include/ct.hrl").
+
+suite() ->
+    [].
+
+all() ->
+    [{group, all_tests}].
+
+groups() ->
+    [{all_tests, [sequence], [error_handling]}].
+
+
+error_handling(_Config) ->
+    mnesia_rocksdb_error_handling:run().
+
+
+init_per_suite(Config) ->
+    Config.
+
+end_per_suite(_Config) ->
+    ok.
+
+init_per_group(_, Config) ->
+    Config.
+
+end_per_group(_, _Config) ->
+    ok.
+
+init_per_testcase(_, Config) ->
+    Config.
+
+end_per_testcase(_, _Config) ->
+    ok.
@@ -0,0 +1,103 @@
+-module(mnesia_rocksdb_error_handling).
+
+-export([run/0,
+         run/4]).
+
+
+run() ->
+    setup(),
+    %% run only one test for 'fatal', to save time.
+    [run(Type, Op, L, MaintainSz) || MaintainSz <- [false, true],
+                                     Type <- [set, bag],
+                                     Op <- [insert, update, delete],
+                                     L <- levels()]
+        ++ [run(set, insert, fatal, false)].
+
+run(Type, Op, Level, MaintainSz) ->
+    setup(),
+    {ok, Tab} = create_tab(Type, Level, MaintainSz),
+    mnesia:dirty_write({Tab, a, 1}),                    % pre-existing data
+    with_mock(Level, Op, Tab, fun() ->
+                                      try_write(Op, Type, Tab),
+                                      expect_error(Level, Tab)
+                              end).
+
+levels() ->
+    [debug, verbose, warning, error].
+
+setup() ->
+    mnesia:stop(),
+    start_mnesia().
+
+create_tab(Type, Level, MaintainSz) ->
+    TabName = tab_name(Type, Level, MaintainSz),
+    UserProps = user_props(Level, MaintainSz),
+    {atomic, ok} = mnesia:create_table(TabName, [{rdb, [node()]},
+                                                 {user_properties, UserProps}]),
+    {ok, TabName}.
+
+tab_name(Type, Level, MaintainSz) ->
+    binary_to_atom(iolist_to_binary(
+                     ["t" | [["_", atom_to_list(A)]
+                                || A <- [?MODULE, Type, Level, MaintainSz]]]), utf8).
+
+user_props(Level, MaintainSz) ->
+    [{maintain_sz, MaintainSz},
+     {rocksdb_opts, [{on_write_error, Level}]}].
+
+start_mnesia() ->
+    mnesia_rocksdb_tlib:start_mnesia(reset),
+    ok.
+
+with_mock(Level, Op, Tab, F) ->
+    mnesia:subscribe(system),
+    mnesia:set_debug_level(debug),
+    meck:new(mnesia_rocksdb_lib, [passthrough]),
+    meck:expect(mnesia_rocksdb_lib, put, 4, {error, some_put_error}),
+    meck:expect(mnesia_rocksdb_lib, write, 3, {error, some_write_error}),
+    meck:expect(mnesia_rocksdb_lib, delete, 3, {error,some_delete_error}),
+    try {Level, Op, Tab, F()} of
+        {_, _, _, ok} ->
+            ok;
+        Other ->
+            io:fwrite("OTHER: ~p~n", [Other]),
+            ok
+    catch
+        exit:{{aborted,_},_} ->
+            Level = error,
+            ok
+    after
+        mnesia:set_debug_level(none),
+        mnesia:unsubscribe(system),
+        meck:unload(mnesia_rocksdb_lib)
+    end.
+
+try_write(insert, set, Tab) ->
+    mnesia:dirty_write({Tab, b, 2});
+try_write(insert, bag, Tab) ->
+    mnesia:dirty_write({Tab, a, 2});
+try_write(update, _, Tab) ->
+    mnesia:dirty_write({Tab, a, 1});
+try_write(delete, _, Tab) ->
+    mnesia:dirty_delete({Tab, a}).
+
+
+expect_error(Level, Tab) ->
+    Tag = rpt_tag(Level),
+    receive
+        {mnesia_system_event, {mnesia_fatal, Fmt, Args, _Core}} ->
+            Tag = mnesia_fatal,
+            io:fwrite("EVENT(~p, ~p):~n  ~s", [Tag, Tab, io_lib:fwrite(Fmt, Args)]),
+            ok;
+        {mnesia_system_event, {Tag, Fmt, Args}} ->
+            io:fwrite("EVENT(~p, ~p):~n  ~s", [Tag, Tab, io_lib:fwrite(Fmt, Args)]),
+            ok
+    after 1000 ->
+            error({expected_error, [Level, Tab]})
+    end.
+
+rpt_tag(fatal  ) -> mnesia_fatal;
+rpt_tag(error  ) -> mnesia_error;
+rpt_tag(warning) -> mnesia_warning;
+rpt_tag(verbose) -> mnesia_info;
+rpt_tag(debug  ) -> mnesia_info.